اف شارپ

Functional programming

F# is a strongly typed functional-first language that uses type inference. Types do not need to be explicitly declared by the programmer; they will be deduced by the compiler during compilation. F# also allows explicit type annotations and requires them in some situations.

F# is an expression-based language using eager evaluation. Every statement in F#, including if expressions, try expressions and loops, is a composable expression with a static type. Functions and expressions that do not return any value have a return type of unit. F# uses the let keyword for binding values to a name. For example:

let x = 3 + 4

binds the value 7 to the name x.

New types are defined using the type keyword. For functional programming, F# provides tuple, record, discriminated union, list and option types. A tuple represents a collection of n values, where n ≥ 0. The value n is called the arity of the tuple. A 3-tuple would be represented as (A, B, C), where A, B and C are values of possibly different types. A tuple can be used to store values only when the number of values is known at design-time and stays constant throughout execution.

A record is a type where the data members are named, as in { Name:string; Age:int }. Records can be created as { Name="AB"; Age=42 }. The with keyword is used to create a copy of a record, as in { r with Name="CD" }, which creates a new record by copying r and changing the value of the Name field (assuming the record created in the last example was named r).

A discriminated union type is a type-safe version of C unions. For example,

 type A =
    | UnionCaseX of string
    | UnionCaseY of int

Values of the union type can correspond to either union case. The types of the values carried by each union case is included in the definition of each case.

The list type is an immutable linked list represented either using a head::tail notation (:: is the cons operator) or a shorthand as [item1; item2; item3]. An empty list is written []. The option type is a discriminated union type with choices Some(x) or None. F# types may be generic, implemented as generic .NET types.

F# supports lambda functions and closures. All functions in F# are first class values and are immutable. Functions can be curried. Being first-class values, functions can be passed as arguments to other functions. Like other functional programming languages, F# allows function composition using the >> and << operators.

F# provides sequence expressions that define a sequence seq { ... }, list [...] or array [| ... |] through code that generates values. For example,

 seq { for b in 0 .. 25 do
 if b <15 then
               yield b*b }

forms a sequence of squares of numbers from 0 to 14 by filtering out numbers from the range of numbers from 0 to 25. Sequences are generated on-demand (i.e. are lazily evaluated), while lists and arrays are evaluated eagerly.

F# uses تطبیق الگو to bind values to names. Pattern matching is also used when accessing discriminated unions - the union is value matched against pattern rules and a rule is selected when a match succeeds. F# also supports Active Patterns as a form of extensible pattern matching. It is used, for example, when multiple ways of matching on a type exist.

F# supports a general syntax for defining compositional computations called computation expressions. Sequence expressions, asynchronous computations and queries are particular kinds of computation expressions. Computation expressions are an implementation of the monad pattern.

Imperative programming

F# support for imperative programming includes

• for loops
• while loops
• arrays, created with the [| ... |] syntax
• hash table, created with the dict [...] syntax or System.Collections.Generic.Dictionary<_,_> type).

Values and record fields can also be labelled as mutable. For example:

// Define 'x' with initial value '1'
let mutable x = 1
// Change the value of 'x' to be '3'
x <- 3

In addition, F# supports access to all CLI types and objects such as those defined in the System.Collections.Generic namespace defining imperative data structures.

Object programming

F#, like other CLI languages, can use CLI types and objects through object programming. F# support for object programming in expressions includes:

• dot-notation (e.g. x.Name)
• object expressions (e.g. { new obj() with member x.ToString() = "hello" })
• object construction (e.g. new Form())
• type tests (e.g. x :? string)
• type coercions (e.g. x :?> string)
• named arguments (e.g. x.Method(someArgument=1))
• named setters (e.g. new Form(Text="Hello"))
• optional arguments (e.g. x.Method(OptionalArgument=1)

Support for object programming in patterns includes

• type tests (e.g. :? string as s)
• active patterns, which can be defined over object types.

F# object type definitions can be class, struct, interface, enum or delegate type definitions, corresponding to the definition forms found in the C#. For example, here is a class with a constructor taking a name and age, and declaring two properties.

/// A simple object type definition
type Person(name : string, age : int) =
    member x.Name = name
    member x.Age = age

Asynchronous programming

F# supports asynchronous programming through asynchronous workflows. An asynchronous workflow is defined as a sequence of commands inside an async{ ... }, as in

let asynctask =
    async { let req = WebRequest.Create(url)
            let! response = req.GetResponseAsync()
            use stream = response.GetResponseStream()
            use streamreader = new System.IO.StreamReader(stream)
            return streamreader.ReadToEnd() }

The let! allows the rest of the async block to be defined as the delegate and passed as the callback function of an asynchronous operation. This solves the inversion of control problem. The async block is invoked using the Async.RunSynchronously function. Multiple async blocks are executed in parallel using the Async.Parallel function that takes a list of async objects (in the example, asynctask is an async object) and creates another async object to run the tasks in the lists in parallel. The resultant object is invoked using Async.RunSynchronously.

Parallel programming

Parallel programming is supported partly through the Async.Parallel, Async.Start and other operations that run asynchronous blocks in parallel.

Parallel programming is also supported through the Array.Parallel functional programming operators in the F# standard library, direct use of the System.Threading.Tasks task programming model, the direct use of .NET thread pool and .NET threads and through dynamic translation of F# code to alternative parallel execution engines such as GPU code.

Units of measure

The F# type system supports units of measure checking for numbers. The units of measure feature integrates with F# type inference to require minimal type annotations in user code.

Metaprogramming

F# allows some forms of syntax customization to support embedding custom domain-specific languages within the F# language itself, particularly through computation expressions.

F# includes a feature for run-time meta-programming called quotations. A quotation expression evaluates to an abstract syntax representation of F# expressions. A definition labelled with the [<ReflectedDefinition>] attribute can also be accessed in its quotation form. F# quotations are used for various purposes including to compile F# code to جاوااسکریپت and GPU code.

Information rich programming

F# 3.0 introduced a form of compile-time meta-programming through statically extensible type generation called F# type providers. F# type providers allow the F# compiler and tools to be extended with components that provide type information to the compiler on-demand at compile time. F# type providers have been used to give strongly typed access to connected information sources in a scalable way, including to the فری‌بیس knowledge graph.

In F# 3.0 the F# quotation and computation expression features are combined to implement لینک (زبان برنامه‌نویسی) queries. For example:

// Use the OData type provider to create types that can be used to access the Northwind database.
open Microsoft.FSharp.Data.TypeProviders

type Northwind = ODataService<"http://services.odata.org/Northwind/Northwind.svc">
let db = Northwind.GetDataContext()

// A query expression.
let query1 = query { for customer in db.Customers do
                     select customer }

The combination of type providers, queries and strongly typed functional programming is known as information rich programming.

Agent programming

F# supports a variation of the Actor programming model through the in-memory implementation of lightweight asynchronous agents. For example, the following code defines an agent and posts 2 messages:

let counter =
    MailboxProcessor.Start(fun inbox ->
        let rec loop n =
            async { do printfn "n = %d, waiting..." n
                    let! msg = inbox.Receive()
                    return! loop(n+msg) }
        loop 0)

F# can be developed with any text editor. Specific support exists in editors such as ایمکس.

The Visual F# tools from Microsoft include full IDE integration in Visual Studio. With the language service installed, Visual Studio can be used to create F# projects and the Visual Studio debugger used to debug F# code. In addition, the Visual F# tools comes with a Visual Studio-hosted REPL interactive console that can be used to execute F# code as it is being written.

WebSharper is a framework for cross-tier JavaScript and HTML5 development with F#.

مونودولاپ is an integrated development environment supporting F# programming on Linux, Mac and Windows including support for the interactive console as used by Visual Studio.

SharpDevelop has supported F# since version 3.0.

لینک‌پد has supported F# since version 2.x.

F# is a general purpose programming language.

Web programming

F# is a central part of the WebSharper framework where F# code is executed as a .NET code on the server and as جاوااسکریپت code on the client-side.

Analytical programming

Among others, F# is used for quantitative finance programming, energy trading and portfolio optimization, machine learning, business intelligence and social gaming on Facebook.

In recent years, F# is placed as optimised alternative of C#, F#'s scripting ability and IL compitablility with all Microsoft products have made it popular amongst developers, many developers create solutions based on F# and expose the functionality using C# WCF Services.

Scripting

F# is often used as a scripting language, mainly for desktop REPL scripting.

The F# open source community includes the F# Software Foundation and the F# Open Source Group at GitHub.

A few small samples follow:

// This is a comment for a sample hello world program.
printfn "Hello World!"

A Person class with a constructor taking a name and age and two properties.

/// This is a documentation comment for a type definition.
type Person(name : string, age : int) =
    member x.Name = name
    member x.Age = age

A simple example that is often used to demonstrate the syntax of functional languages is the factorial function for non-negative 32-bit integers, here shown in F#:

/// This is a documentation comment for a function.
let rec factorial n =
    match n with
    | 0 -> 1
    | _ -> n * factorial (n - 1)

Iteration examples:

/// Iteration using a 'for' loop
let printList lst =
    for x in lst do
        printfn "%d" x

/// Iteration using a higher-order function
let printList2 lst =
    List.iter (printfn "%d") lst

/// Iteration using a recursive function and pattern matching
let rec printList3 lst =
    match lst with
    | [] -> ()
    | h :: t ->
        printfn "%d" h
        printList3 t

Fibonacci examples:

/// Fibonacci Number formula
let rec fib n =
    match n with
    | 0 | 1 -> n
    | _ -> fib (n - 1) + fib (n - 2)

/// Another approach - a lazy infinite sequence of Fibonacci numbers
let fibSeq = Seq.unfold (fun (a,b) -> Some(a+b, (b, a+b))) (0,1)

// Print even fibs
[1 .. 10]
|> List.map fib
|> List.filter (fun n -> (n % 2) = 0)
|> printList

// Same thing, using a list expression
[ for i in 1..10 do
    let r = fib i
    if r % 2 = 0 then yield r ]
|> printList

A sample Windows Forms program:

// Open the Windows Forms library
open System.Windows.Forms

// Create a window and set a few properties
let form = new Form(Visible=true, TopMost=true, Text="Welcome to F#")

// Create a label to show some text in the form
let label =
    let x = 3 + (4 * 5)
    new Label(Text = sprintf "x = %d" x)

// Add the label to the form
form.Controls.Add(label)

// Finally, run the form
[<System.STAThread>]
Application.Run(form)

Asynchronous parallel programming sample (parallel CPU and I/O tasks):

/// A very naive prime number detector
let isPrime (n:int) =
   let bound = int (sqrt (float n))
   seq {2 .. bound} |> Seq.forall (fun x -> n % x <> 0)

// We are using async workflows
let primeAsync n =
    async { return (n, isPrime n) }

/// Return primes between m and n using multiple threads
let primes m n =
    seq {m .. n}
        |> Seq.map primeAsync
        |> Async.Parallel
        |> Async.RunSynchronously
        |> Array.filter snd
        |> Array.map fst

// Run a test
primes 1000000 1002000
    |> Array.iter (printfn "%d")

• اکمل
• C#
• چارچوب دات‌نت
• Scala
• کلوژر
• Haskell
• Nemerle

• Syme, Don; Granicz, Adam; Cisternino, Antonio (2007). "Expert F#". Apress.
• Harrop, Jon (2010). "Visual F# 2010 for Technical Computing". Flying Frog Consultancy.
• Pickering, Robert (2007). "Foundations of F#". Apress.
• Smith, Chris (2009). "Programming F#". O'Reilly.
• Petricek, Tomas (2009). "Real World Functional Programming With Examples in F# and C#". Manning Publications.
• Hansen, Michael; Rischel, Hans (2013). "Functional Programming Using F#". Cambridge University Press.

• The F# Software Foundation
• The F# Open Source Group at GitHub بایگانی‌شده در ۱ فوریه ۲۰۱۳ توسط Wayback Machine
• The Visual F# Developer Center
• Tsunami, an embeddable desktop F# IDE
• Cloud Tsunami, an embeddable Silverlight F# IDE
• Try F#, for learning F# in your browser
• F# Snippets Site
• The Visual F# team blog
• The original Microsoft Research website for F#
• Planet F# بایگانی‌شده در ۱۳ فوریه ۲۰۰۹ توسط Wayback Machine
• The F# Survival Guide, دسامبر ۲۰۰۹ (Web-based book)
• The F# Language Specification
• An introduction to F# programming
• F# Tutorials for Beginning through Advanced Learners